home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib12.dsk / PEEKING AND TWEAKING DOS.bas < prev    next >
Encoding:
BASIC Source File  |  1990-01-01  |  3.4 KB  |  82 lines
  1. 10  REM  **********************
  2. 20  REM  * PEEK & TWEAK DOS   *
  3. 30  REM  * BY S. KARATSORIDIS *
  4. 40  REM  * AFTER AN ARTICLE   *
  5. 50  REM  * BY DOUG HENNIG     *
  6. 60  REM  * COPYRIGHT (C) 1983 *
  7. 70  REM  * BY MICRO-SPARC INC *
  8. 80  REM  * LINCOLN, MA. 01773 *
  9. 90  REM  **********************
  10. 100  HOME 
  11. 110 A$ = "PEEKING AND TWEAKING DOS"
  12. 120  GOSUB 1000
  13. 130 A$ = "BY DOUG HENNIG": GOSUB 1000
  14. 140  PRINT : PRINT :A$ = "PROGRAM BY STAVROS KARATSORIDIS"
  15. 150  GOSUB 1000
  16. 160  VTAB 21: PRINT "** COPYRIGHT 1983 BY MICROSPARC, INC. **"
  17. 170  VTAB 15:A$ = "PRESS ANY KEY TO CONTINUE": INVERSE : GOSUB 1000: NORMAL 
  18. 180  POKE  -16368,0: WAIT  -16384,128: POKE  -16368,0
  19. 190  HOME 
  20. 200  VTAB 3:A$ = "*** MAIN MENU ***": GOSUB 1000: PRINT : PRINT 
  21. 210  HTAB 4: PRINT "1. DISPLAY DELETED FILES": PRINT 
  22. 220  HTAB 4: PRINT "2. DISPLAY FREE SECTORS": PRINT 
  23. 230  HTAB 4: PRINT "3. ESCAPE FROM A CATALOG": PRINT 
  24. 240  HTAB 4: PRINT "4. PREVENT NOT DIRECT COMMAND ERRORS": PRINT 
  25. 250  HTAB 4: PRINT "5. LOWER CASE TEXT IN TEXT FILES": PRINT 
  26. 260  HTAB 4: PRINT "6. "; CHR$(34);"WILD CARD"; CHR$(34);" FILE NAMES": PRINT 
  27. 270  HTAB 4: PRINT "7. EXIT PROGRAM": PRINT : PRINT 
  28. 280  HTAB 4: INVERSE : PRINT "YOUR CHOICE";: NORMAL : GET B$
  29. 290  IF B$ <"1"  OR B$ >"7"  THEN 200
  30. 300 B =  VAL(B$): ON B GOTO 400,500,600,700,800,900,310
  31. 310  HOME : PRINT "BYE!": END 
  32. 400  HOME :A$ = "DISPLAY DELETED FILES": GOSUB 1000
  33. 410  PRINT : PRINT "INSTALLING PATCH..."
  34. 420 P$ = "ADD9:85 6": GOSUB 2000
  35. 430 P$ = "ADFE:4C EA BC": GOSUB 2000
  36. 440 P$ = "BCEA:20 ED FD A5 6 10 A 8A 48 20 48 F9 68 AA 4C E AE 4C 1 AE"
  37. 450  GOSUB 2000
  38. 460  GOSUB 3000
  39. 470  HOME : GOTO 200
  40. 500  HOME :A$ = "DISPLAY FREE SECTORS": GOSUB 1000
  41. 510  PRINT : PRINT "INSTALLING PATCH..."
  42. 520 P$ = "ADC0:20 69 BA": GOSUB 2000
  43. 530 P$ = "BA69:A9 0 85 40 85 41 A0 C8 18 B9 F2 B3 F0 E A 90 FB 48 E6 40 D0 2 E6 41 68 18 90 F0 88 D0 E9 A6 40 A5 41 20 24 ED 60": GOSUB 2000
  44. 540 P$ = "B3AF:A0 BD A0 D4 C3 C5 D3 A0 C5 C5 D2 C6"
  45. 550  GOSUB 2000
  46. 560  GOSUB 3000
  47. 570  HOME : GOTO 200
  48. 600  HOME :A$ = "ESCAPE FROM A CATALOG": GOSUB 1000
  49. 610  PRINT : PRINT "INSTALLING PATCH..."
  50. 620 P$ = "AE39:20 DF BC": GOSUB 2000
  51. 630 P$ = "BCDF:20 1B FD C9 9B F0 1 60 4C 2C AE"
  52. 640  GOSUB 2000
  53. 650  GOSUB 3000
  54. 660  HOME : GOTO 200
  55. 700  HOME :A$ = "PREVENT NOT DIRECT COMMAND ERRORS": GOSUB 1000
  56. 710  PRINT : PRINT "INSTALLING PATCH..."
  57. 720 P$ = "A021:EA EA EA"
  58. 730  GOSUB 2000
  59. 740  GOSUB 3000
  60. 750  HOME : GOTO 200
  61. 800  HOME :A$ = "LOWER CASE TEXT IN TEXT FILES": GOSUB 1000
  62. 810  PRINT : PRINT "INSTALLING PATCH..."
  63. 820 P$ = "A649:FF N A657:0"
  64. 830  GOSUB 2000
  65. 840  GOSUB 3000
  66. 850  HOME : GOTO 200
  67. 900  HOME :A$ =  CHR$(34) +"WILD CARD" + CHR$(34) +" FILE NAMES": GOSUB 1000
  68. 910  PRINT : PRINT "INSTALLING PATCH..."
  69. 920 P$ = "B201:4C 58 A4": GOSUB 2000
  70. 930 P$ = "A450:E8 B1 42 DD C6 B4 D0 A C8 C0 1E D0 F3 AE 9C B3 18 60 C9 AD F0 F7 4C B B2"
  71. 940  GOSUB 2000
  72. 950  PRINT : PRINT : FLASH : PRINT "WARNING!";: NORMAL : PRINT " THE INT COMMAND IS DISABLED.": PRINT : PRINT : GOSUB 3000
  73. 960  HOME : GOTO 200
  74. 999  END 
  75. 1000  HTAB 20 -( LEN(A$)/2): PRINT A$: RETURN 
  76. 2000 P$ = P$ +" N D9C6G"
  77. 2010  PRINT : PRINT P$
  78. 2020  FOR J = 1 TO  LEN(P$): POKE 511 +J, ASC( MID$ (P$,J,1)) +128: NEXT J: POKE 72,0: CALL  -144
  79. 2030  RETURN 
  80. 3000  PRINT : PRINT "PATCH INSTALLED.": PRINT : PRINT : INVERSE : PRINT "PRESS SPACE BAR TO RETURN TO MENU": PRINT "OR ANY OTHER KEY TO QUIT";: GET B$
  81. 3010  NORMAL : IF B$ < >" "  THEN  PRINT : PRINT : END 
  82. 3020  RETURN